发表回复 
显示透明文字函数 TransTip()
2019-04-19, 00 : 23 (这个帖子最后修改于: 2019-04-22 12 : 43 by feiyue.)
显示透明文字函数 TransTip()
写了个显示透明文字函数,用于提醒一些情况。由于可以点击穿透所以不会影响电脑操作。
也许有人需要呢。Smile


代码: (全选)
;------------------------------
; 显示透明文字函数:TransTip()  By FeiYue
; s ------> 显示的文字,如果为空,会清除当前的显示
; x, y ---> 显示的屏幕坐标
; font ---> 设定字体大小、颜色和样式,采用Gui的Font命令格式
;------------------------------

TransTip(s="", x=500, y=0, font="s36 cRed bold")
{
  static
  if (s="")
  {
    last:=""
    Gui, TransTip: Destroy
    return
  }
  if (last != font "|" s)
  {
    last:=font "|" s, last_xy:=""
    ;------------------
    Gui, TransTip: Destroy
    Gui, TransTip: +AlwaysOnTop -Caption +ToolWindow +Hwndid +E0x20
    Gui, TransTip: Margin, 0, 0
    Gui, TransTip: Color, EEAA99
    Gui, TransTip: Font, Q3 %font%
    Gui, TransTip: Add, Text,, %s%
    Gui, TransTip: Show, Hide, TransTip
    ;------------------
    dhw:=A_DetectHiddenWindows
    DetectHiddenWindows, On
    WinSet, TransColor, EEAA99 150, ahk_id %id%
    DetectHiddenWindows, %dhw%
  }
  Gui, TransTip: +AlwaysOnTop
  if (last_xy != x "|" y)
  {
    last_xy:=x "|" y, x:=Round(x), y:=Round(y)
    Gui, TransTip: Show, NA x%x% y%y%
  }
}

;-- 滚动显示信息的例子
txt:=A_YYYY "年" A_MM "月" A_DD "日"
SetBatchLines, -1
Loop, % A_ScreenWidth
  TransTip(txt, A_ScreenWidth-A_Index, 0, "s36 cRed bold")
return

Pause::Pause

F1:: (ok:=!ok) ? TransTip("你好!", 600, 200, "s72") : TransTip()
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2019-04-24, 22 : 00
RE: 显示透明文字函数 TransTip()
屏幕抓字生成字库工具与找字函数 v5.6该更新了
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
发表回复 


论坛跳转:


联系我们 | Autohotkey 中文站 | 回到顶部 | 回到正文区 | 精简(归档)模式 | RSS 聚合