发表回复 
问题·已解决 音量调节进度条导致无法连续调整
2016-04-01, 17 : 21 (这个帖子最后修改于: 2016-04-05 17 : 11 by robertL.)
音量调节进度条导致无法连续调整
下面代码实现用 F2减少音量,用F3 增加音量
目前的问题是:如果连续的操作由于下面有一个进度条sleep,1500显示
这样会导致连续操作不能顺畅进行
请问,有什么办法既能显示进度条又能在连续按下时顺畅的调音呢?[/code]

;========================================[/code]
F2::
SoundPlay *-1,1
SoundSet, -5
SoundGet, master_volume
Progress, b w800, 当前音量, %master_volume%, My Title
Progress, %master_volume% ; 设置进度条的位置
Sleep, 1500
Progress, Off
return
F3::
SoundPlay *-1,1
SoundSet, +5
SoundGet, master_volume
Progress, b w800, 当前音量, %master_volume%, My Title
Progress, %master_volume% ; 设置进度条的位置
Sleep, 1500
Progress, Off
Return
;========================================
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2016-04-01, 18 : 43 (这个帖子最后修改于: 2016-04-02 00 : 19 by feiyue.)
RE: 音量调节进度条导致无法连续调整
@我软件我做主2 这样就可以了。Smile

代码: (全选)
^Right::
^Up::Goto, vol+

^Left::
^Down::Goto, vol-

vol+:
vol-:
SoundPlay, *-1
SoundSet, % InStr(A_ThisLabel,"+") ? "+5" : "-5"
SoundGet, master_volume
pid:=DllCall("GetCurrentProcessId")
IfWinNotExist, My Title ahk_pid %pid%
  Progress, b w800, 当前音量, ., My Title
Progress,,, % Round(master_volume)
Progress, %master_volume%
SetTimer, ProgressOff, -1000
Return
ProgressOff:
Progress, Off
return
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
[+] 1用户表示感谢feiyue
2016-04-01, 21 : 23 (这个帖子最后修改于: 2016-04-01 21 : 24 by 我软件我做主2.)
RE: 音量调节进度条导致无法连续调整
[quote='feiyue' pid='34809' dateline='1459507427']

多谢,这个代码好!精简!,加了判断后进度窗口不闪了
我最终使用的去掉了音量值显示

代码: (全选)
^Right::
^Up::Goto, vol+

^Left::
^Down::Goto, vol-

vol+:
vol-:
SoundPlay, *-1
SoundSet, % InStr(A_ThisLabel,"+") ? "+2" : "-2"
SoundGet, master_volume
IfWinNotExist, My Title,
  Progress, b w800, , , My Title
Progress, %master_volume%
SetTimer, ProgressOff, -1500
Return
ProgressOff:
Progress, Off
return
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2016-04-02, 17 : 59
RE: 音量调节进度条导致无法连续调整
不过个人感觉还是有点不完美,因为总是有个进度条从0→初始位置的过程。
如初始音量为80时,能够从80处直接动就好了,而不是先从0→80,再逐渐增加或递减。
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2016-04-04, 18 : 00
RE: 音量调节进度条导致无法连续调整
上面的代码就是从当前音量开始的
你哪边测试不行吗?
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2016-04-05, 20 : 00
RE: 音量调节进度条导致无法连续调整
(2016-04-04 18 : 00)我软件我做主2 提到:  上面的代码就是从当前音量开始的
你哪边测试不行吗?

是从当前音量。
不过是这样的:按了快捷键后,绿色进度条是自动先从0移动到当前音量位置。然后再以当前音量为基础,增大或减小。
我强调的重点是:初次按下后,眼睛看到是进度条从无→有→当前音量(消耗1s时间)。假如是100的音量,会看到进度条从出现自动运动到100%,然后再减小。我想看到的​是,按下快捷键看到就是100%的位置。而非从0→移动到100后再减小。
假如还是不清楚,我就用gif来表示。
我想应该描述的很清楚了吧。
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2016-04-05, 20 : 27 (这个帖子最后修改于: 2016-04-05 23 : 47 by feiyue.)
RE: 音量调节进度条导致无法连续调整
@zhanglei1371 真的看的清过程吗?是不是电脑配置太低了?
改用下面的代码试试:

代码: (全选)
^Right::
^Up::Goto, vol+

^Left::
^Down::Goto, vol-

vol+:
vol-:
SoundPlay, *-1
SoundSet, % InStr(A_ThisLabel,"+") ? "+2" : "-2"
SoundGet, master_volume
pid:=DllCall("GetCurrentProcessId")
IfWinNotExist, My Title ahk_pid %pid%
{
  Progress, Hide b w800, , , My Title
  Progress, %master_volume%
  Progress, Show
}
else
  Progress, %master_volume%
SetTimer, ProgressOff, -1500
Return
ProgressOff:
Progress, Off
return
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2016-04-05, 21 : 57
RE: 音量调节进度条导致无法连续调整
(2016-04-05 20 : 27)feiyue 提到:  @zhanglei1371 真的看的清过程吗?是不是电脑配置太低了?
改用下面的代码试试:

代码: (全选)
^Right::
^Up::Goto, vol+

我的配置:
Win7 64
4核,笔记本
下面是两个gif:
[Image: 1459864554x1035372866.gif]
[Image: 1459864580x1035372896.gif]
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2016-04-05, 23 : 07 (这个帖子最后修改于: 2016-04-05 23 : 50 by feiyue.)
RE: 音量调节进度条导致无法连续调整
@zhanglei1371 你试试Gui版本的看看:

代码: (全选)
^Right::
^Up::Goto, vol+

^Left::
^Down::Goto, vol-

vol+:
vol-:
SoundPlay, *-1
SoundSet, % InStr(A_ThisLabel,"+") ? "+2" : "-2"
SoundGet, master_volume
pid:=DllCall("GetCurrentProcessId")
IfWinNotExist, My Title ahk_pid %pid%
{
  Gui, MyVol:New, +AlwaysOnTop -Caption +ToolWindow +Disabled
  Gui, MyVol:Margin, 10, 10
  Gui, MyVol:Add, Progress, w800 r1.5 vMyProgress -Smooth, %master_volume%
  Gui, MyVol:Show, NoActivate, My Title
}
else
  GuiControl, MyVol:, MyProgress, %master_volume%
SetTimer, MyVolGuiClose, -1500
Return
MyVolGuiClose:
Gui, MyVol:Destroy
Return
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2016-04-06, 15 : 17
RE: 音量调节进度条导致无法连续调整
(2016-04-05 23 : 07)feiyue 提到:  @zhanglei1371 你试试Gui版本的看看:

代码: (全选)
^Right::
^Up::Goto, vol+

^Left::
^Down::Goto, vol-

vol+:
vol-:

还是一样哦。。。。
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2016-04-06, 18 : 23
RE: 音量调节进度条导致无法连续调整
这是一个效果,系统特意为之,,,,
你可以尝试把上面的代码里面的
-Smooth去掉,或者改成cGreen cRed之类的
看是否你想要的效果。。。。

尊重原创,分享快乐
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
2017-09-17, 13 : 41
RE: 音量调节进度条导致无法连续调整
只调音量,不调波形,不太令人满意。
查找这个用户的全部帖子
表示感谢 引用并回复 移动视图置页面顶端
发表回复 


论坛跳转:


联系我们 | Autohotkey 中文站 | 回到顶部 | 回到正文区 | 精简(归档)模式 | RSS 聚合